App.Db.InsertBatch - API 文档

## App.Db.InsertBatch
方法，批量插入记录
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-code"></i> 语法</label></h4>
```asp
App.Db.InsertBatch(conn, table, fieldValues)
```
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-cogs"></i> 参数</label></h4>
|参数|类型|说明
| ------------ | ------------ |
|conn|Object(ASP对象)|数据库对象
|table|String(字符串)|数据表名称
|fieldValues|String(字符串)|逗号隔开的 `字段:值` 序列
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-reply"></i> 返回值</label></h4>
|类型|说明
| ------------ | ------------ |
|Integer(整数)|受影响的行数
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-info-circle"></i> 说明</label></h4>
批量插入记录，参数 `fieldValues` 为逗号隔开的 `字段:值` 序列，如果您要更改默认的字段分隔符号（默认为半角逗号），可以设置下面的属性：
```asp
App.Db.InsertSeparator = "#"
```
这样就可以用 `#` 分隔 `字段:值` 序列了。
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-plug"></i> 示例</label></h4>
```asp
App.Db.SetConnection "acc",1,"/db/db.mdb",""
Set Conn = App.Db.GetConnection("acc")
App.Var("name") = Array("刘六","赵四","李五")
App.Var("age") = Array(36,46,57)
App.Var("sex") = Array("女","男","男")
App.W App.Db.InsertBatch(Conn, "easp_test", "id:{easp.newid},name:{name},age:{age},sex:{sex}")
```
浏览器返回：
```asp
3
```
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-tag"></i> 应用场景 & 使用心得</label></h4>
#### 关于批量操作
首先要说说这里的批量操作并不是指用一条SQL语句删除相同条件的多条记录，而是指批量操作多条本应该单独执行的SQL语句，比如批量插入、按ID号批量更新、删除等。 这里举个简单的插入数据的例子循序渐进的来看看 API 的批量操作是如何工作的：
我们假设用户要向数据库的 `ProductClass` 表插入一条记录，所以在HTML页面上构建了如下的表单代码：
```asp
<form action="insert.asp?action=save" method="post">
  <input type="text" name="productclassname" />
  <input type="submit" value="Submit">
</form>
```
那么用 API 写的插入一条数据的完整代码如下：
```asp

<%
If App.Get("action") = "save" Then
  Dim result
  result = App.Db.Ins("ProductClass", "class_id:{easp.newid}, class_name:{productclassname}")
  '上面的 {easp.newid} 会生成一个唯一不重复的可排序10位字符串，推荐用于数据表的主键ID字段'
  If result > 0 Then App.JsAlert("插入成功！")
End If
%>
```
现在我们要让用户可以批量插入数据，于是我们将 HTML 页面的代码修改为一次可以输入4个 `productclassname`：
```asp
<form action="insert.asp?action=save" method="post">
  <input type="text" name="productclassname" /> <br />
  <input type="text" name="productclassname" /> <br />
  <input type="text" name="productclassname" /> <br />
  <input type="text" name="productclassname" /> <br />
  <input type="submit" value="Submit">
</form>
```
请注意，上面的文本框的 name 值都是一样的，所以在服务器端，会接收到一个序列而不是单个文本框的值。而后台代码则只需要做出非常少的修改就行了：
```asp

<%
If App.Get("action") = "save" Then
  Dim result
  result = App.Db.InsBatch("ProductClass", "class_id:{easp.newid}, class_name:{productclassname}")
  '批量操作函数里的 {easp.newid} 会为每条记录生成一个新ID'
  If result > 0 Then App.JsAlert(result & "条记录插入成功！")
End If
%>
```
相信你可以看得出来，API 中的数据库批量操作基本上和操作一般的查询是一样的，只是方法名有所不同而已。 下面列出了 API 所有可用的数据库批量操作方法：
```asp
'用于默认数据库连接的方法'
'批量执行SQL（注：Select 语句不能用于批量操作）'
result = App.Db.ExecBatch(sql)
'批量新增记录'
result = App.Db.InsBatch(table, field:value[,field:value...])
'批量更新记录'
result = App.Db.UpdBatch(table, field=value[,field=value...], where)
'批量删除记录'
result = App.Db.DelBatch(table, where)
'用于非默认数据库连接的方法'
result = App.Db.ExecuteBatch(conn, sql)
'批量新增记录'
result = App.Db.InsertBatch(conn, table, field:value[,field:value...])
'批量更新记录'
result = App.Db.UpdateBatch(conn, table, field=value[,field=value...], where)
'批量删除记录'
result = App.Db.DeleteBatch(conn, table, where)
```
上面的方法返回的都受影响的行数。
除了可以接收表单提交的序列值之外，也可以手动代入数组值用于批量操作时的参数，比如：
```asp
Dim result
App.Var("id") = Array(12,23,45,34,67,89,90)
'下面的两种方法都是正确的，第二种方法效率更高：'
'方法一，直接写SQL语句'
result = App.Db.ExecBatch("delete from product where id = {id}")
'方法二，用批量删除方法，会自动优化SQL语句，效率更高'
result = App.Db.DelBatch("product", "id = {id}")
```
上面的代码会删除 `product` 表中所有 `id` 在数组中的值。API 中的批量新增、删除、更新方法都会自动优化SQL语句，效率会有非常高的提升，在批量操作时建议使用这些方法。
<h4 class="font-thin"><label class="label bg-info text-white"><i class="fa fa-terminal"></i> 源码解析</label></h4>
core/easp.db.asp 第 1228 行：
```asp
Public Function InsertBatch(ByRef conn, ByVal table, ByVal fieldValues)
	On Error Resume Next
	InsertBatch = InsertRecord(conn, table, fieldValues, True)
	CheckError "insertbatch", Err, conn, "InsertBatch", Array(table, fieldValues)
End Function
```